home *** CD-ROM | disk | FTP | other *** search
/ Suzy B Software 2 / Suzy B Software CD-ROM 2 (1994).iso / extras / falcon / bwing105 / bwrestor.s < prev    next >
Text File  |  1995-04-27  |  3KB  |  99 lines
  1. ;
  2. ; Bird's Wings Restore 1.12
  3. ;
  4. ; RéInstalle l'écran virtuel pour Bird's Wings, dans le cas ou
  5. ; un programme ne remettrait pas correctement la résolution
  6. ; 
  7. ; Remet les adresses écran et le mode vidéo
  8. ; Note: Les appels Xbios doivent se faire en mode utilisateur
  9. ;
  10.  
  11.  
  12.         Section TEXT    ; .TEXT tout court dans certains compilateurs
  13.  
  14. Cookoo:
  15.  Pea    Gato            ; Bonjour!
  16.  Move.W #9,-(Sp)        ; Print
  17.  Trap   #1              ; Appel GEMDOS
  18.  Addq.L #6,Sp           ; Corriger pile
  19.  
  20. Super:  
  21.  Clr.L  -(Sp)           ; Mode superviseur
  22.  Move.W #32,-(Sp)       ; Super
  23.  Trap   #1              ; Appel GEMDOS
  24.  Addq.L #6,Sp           ; Corriger pile
  25.  Move.L D0,D7           ; Mettre ancienne pile à l'abri
  26.  
  27. TstCook:
  28.  Tst.L  $5A0.W          ; Une jar au moins?
  29.  Ble.s  NoCook          ; Non, c'est quoi ce micmac?
  30.  Move.L $5A0.W,a6       ; La boiboite à gato
  31. CookL:
  32.  Move.L (a6)+,d0        ; On en prend un
  33.  Beq.s  NoCook          ; Un gateau creux?
  34.  Cmp.L  #'WBrd',d0      ; Notre gâto?
  35.  Beq.s  OkCook          ; Ouais!
  36.  Addq.L #4,a6           ; Suivant!
  37.  Bra.s  CookL           ; Et ca repart
  38.  
  39. OkCook:
  40.  Move.L (A6),A6         ; Adresse bloc B.W. (offset 0= adresse écran)
  41.  
  42.                         ; Note: le SetScreen en mode utilisateur!
  43.  Move.L D7,-(Sp)        ; Ancienne pile utilisateur
  44.  Move.W #32,-(Sp)       ; Super
  45.  Trap   #1              ; Appel GEMDOS
  46.  Addq.l #6,Sp           ; Corriger pile (la pauvre décidément)
  47.  
  48.  Move.W #-1,-(Sp)       ; Demander mode (fictif, car seul le bit 12 est important)
  49.  Move.W #88,-(Sp)       ; VSetMode
  50.  Trap   #14             ; Appel XBIOS
  51.  Addq.L #4,Sp           ; Corriger pile
  52.  Bset.L #12,D0          ; Bit #12 de Bird's Wings : ordre de réinstallation
  53.  
  54. Setscreen:
  55.  Move.W D0,-(Sp)        ; Mode (seul le bit 12 est nécessaire en fait)
  56.  Move.W #3,-(Sp)        ; SetMode
  57.  Move.L (A6),-(Sp)      ; Adresse écran Bird's Wings
  58.  Move.L (A6),-(Sp)      ; Idem
  59.  Move.W #5,-(Sp)        ; SetScreen
  60.  Trap   #14             ; Appel XBIOS
  61.  Add.L  #12,Sp          ; Corriger pile
  62.  
  63.  Bra.s  End             ; Ok all good
  64.  
  65. NoCook:
  66.  Pea    Bah             ; Euh erreur
  67.  Move.W #9,-(Sp)        ; Print
  68.  Trap   #1              ; Appel GEMDOS
  69.  Addq.L #6,Sp           ; Corriger pile
  70.  
  71.  Move.W #7,-(Sp)        ; Attendre une touche sinon il va rien voir et rien comprendre l'autre
  72.  Trap   #1              ; Appel GEMDOS
  73.  Addq.L #2,Sp           ; Corriger pile
  74.  
  75. Suite:
  76.  Move.L D7,-(Sp)        ; Ancienne pile utilisateur
  77.  Move.W #32,-(Sp)       ; Super
  78.  Trap   #1              ; Appel GEMDOS
  79.  Addq.l #6,Sp           ; Corriger pile (la pauvre décidément)
  80.  
  81. End:
  82.  Clr.W  -(Sp)           ; PTerm
  83.  Trap   #1              ; Appel j'aime DOS
  84.  
  85.  
  86.         Section DATA    ; ou .DATA
  87.  
  88.  Even                   ; Even and Hell (...)
  89.  
  90.  Gato:  Dc.b    27,"E","WRestore 1.1 pour Bird's Wings",13,10
  91.         Dc.b    "Réinstalle l'écran",13,10
  92.         Dc.b    0
  93.  
  94.  Even
  95.  
  96.  Bah:   Dc.b    10,"Bird's Wings non installé, arrêtez la tisane .. ou lisez la DOC!",13,10,0
  97.  
  98.  
  99.